@=~
~p typesetter = texinfo
~p maximum_input_line_length = infinity


~O~<qbe.QueryView.sl~>~{



CHAIN ListElementNumber: int;

SYMBOL ListElementNumberRoot
COMPUTE
  CHAINSTART HEAD.ListElementNumber=0;
END;

SYMBOL ListElementNumberClass
COMPUTE
  SYNT.ListElementNumber=ADD(THIS.ListElementNumber,1);
END;

/* *********** */

SYMBOL QueryDef INHERITS VP_Form
COMPUTE
  SYNT.VP_OptDrawing=ADDROF(QueryDefDrawing);
END;

SYMBOL QueryName INHERITS VP_TextTerminal, VP_ContainerSSS
COMPUTE
  SYNT.VP_OptText=THIS.persName;
  SYNT.VP_OblContainerName="Name";
  SYNT.VP_OptFont="headline";
END;

SYMBOL TableInstances INHERITS VP_SimpleList, VP_ContainerSSS
COMPUTE
  SYNT.VP_OblContainerName="Body";
  SYNT.VP_OptMinWidth2=100;
  SYNT.VP_OptElementDistance=30;
  SYNT.VP_OptInsPointProc = "::instanz::insert_applied_pattern";
  SYNT.VP_OptInsPointProcArgs = VLAPPEND(VLLIST(),"persTableDefInstConnection");
  SYNT.VP_OptAlignInWidth = VisAlignLeft;
END;

SYMBOL _List_TableInstance INHERITS VP_ListContext END;


SYMBOL TableInstance INHERITS VP_Table 
COMPUTE
  SYNT.VP_OptInDirectionBorderLineStyle=NULL;
  SYNT.VP_OptOrthDirectionBorderLineStyle=NULL;
END;

SYMBOL TableDefName INHERITS VP_TextTerminal, VP_ContainerSSS
COMPUTE
  SYNT.VP_OptText=INCLUDING TableInstance.pers3TableDefName;
  SYNT.VP_OblContainerName="leftSide";
END;

SYMBOL _List_TableInstanceHeadElement INHERITS ListElementNumberRoot END;

SYMBOL TableInstanceHeadElement INHERITS VP_ContainerSSS, VP_TextTerminal, ListElementNumberClass
COMPUTE
  SYNT.VP_OptText=THIS.pers3Name;
  SYNT.VP_OblContainerName=GETVLSTRING(sprintf(VLStringBuffer,"%i",THIS.ListElementNumber));
END;

SYMBOL _List_TableInstanceLine INHERITS VP_ListContext END;

SYMBOL TableInstanceLine INHERITS VP_ComplexElement END;

SYMBOL _List_TableInstanceLineElement INHERITS ListElementNumberRoot END;

SYMBOL TableInstanceLineElement INHERITS VP_ContainerSSS, VP_Form, ListElementNumberClass
COMPUTE
  SYNT.VP_OblContainerName=GETVLSTRING(sprintf(VLStringBuffer,"%i",THIS.ListElementNumber));
  SYNT.VP_OptDrawing=ADDROF(TableInstanceLineElementDrawing);
  SYNT.VP_OptAlign=VisIntVector(VisAlignScale,VisAlignScale);
END;

SYMBOL Condition INHERITS VP_ContainerSSS, VP_TextTerminal, ListElementNumberClass
COMPUTE
  SYNT.VP_OblContainerName="Condition";
  SYNT.VP_OptDefault="";
  SYNT.VP_OptFrameDrawing=NEW(FrameDrawing("-fill white -outline {}",0));
  SYNT.VP_OptText=VLCharPtr(THIS.persValue);
END;

SYMBOL Print INHERITS VP_ContainerIPL
COMPUTE
  SYNT.VP_OblContainerName="Print";
END;

SYMBOL PrintAs INHERITS VP_TextTerminal
COMPUTE
  SYNT.VP_OptText=IF(strcmp(THIS.persName,""),
    VLCharPtr(GETVLSTRING(sprintf(VLStringBuffer,"Print as %s",VLCharPtr(THIS.persName)))),
    VLCharPtr("P."));
  SYNT.VP_OptFill="darkgreen";
  SYNT.VP_OptFont="default";
END;

SYMBOL Quantor INHERITS VP_ContainerSSS, VP_TextTerminal
COMPUTE
  SYNT.VP_OptText=IF(THIS.persNot,VLCharPtr("not"),VLCharPtr("  "));
  SYNT.VP_OptFill="red";
  SYNT.VP_OblContainerName="leftSide";
  SYNT.VP_OptFrameDrawing=NEW(FrameDrawing("-fill white -outline {}",0));
  SYNT.VP_OptAlign=VisIntVector(VisAlignScale,VisAlignScale);
END;

~}